#!/usr/bin/env perl
#
# make2csv - translate make -p output to CSV format
#
# $Id$

use warnings;
use strict;

use Getopt::Std;
use Text::CSV_XS;

my %opt;
getopts( 'h?dt:', \%opt );

HELP_MESSAGE() if $opt{'h'} || $opt{'?'};

my $sep = $opt{'t'} // ',';

my $csvh = new Text::CSV_XS( { sep_char => $sep, eol => $/ } )
 or die "the CSV writer doesn't work (not installed?)\n";

doit();
exit(0);

sub HELP_MESSAGE
{
  print STDERR <<ZZ;

Usage: $0 [-t sep] [file1 [file2 [...]]]

to convert the input file(s), or standard input,
from makefile syntax (i.e. make -p output) to CSV format.

The output is a CSV file in which each line has one or two columns.
The first column always contains a target.
The second contains a dependency or a symbolic representation
of a recipe (as \@1, \@2, \@3, ...)

Options:

  -t sep
    Use sep (a string) as output field separator (instead of a comma).

  -d
   Print debugging info: the parsing status for every line.

Bugs:

The parser assumes that all words that follow the : in rule headers
are dependencies, which isn't correct for certain sorts of rules.

ZZ

  exit(0);
}

sub dinfo
{
  warn shift(@_), " at $ARGV:$.: $_\n" if $opt{'d'};
}

sub oomph
{
  warn join( ' ', @_ ), " at $ARGV:$.\n";
}

sub doit
{
  my $line    = '';
  my $r       = 0;           # number of recipe blocks
  my $state   = 'outside';
  my @targets = ();

  while (<>)
  {
    chomp;

    if (/\\$/)
    {
      $line .= $_ . ' ';
      next;
    }

    $_    = $line . $_;
    $line = '';

    if (/^#/)
    {
      # comment - ignore, does not affect $state
      dinfo('comment');
      next;
    }
    elsif (/^\t/)
    {
      # a recipe line
      if ( $state eq 'outside' )
      {
        oomph('ignoring recipe line outside rule');
      }
      elsif ( $state eq 'rule' )
      {
        $csvh->print( *STDOUT, [ $_, '@' . ++$r ] ) for @targets;
        $state = 'recipe';
      }
    }
    elsif ( my ( $targets, $dependencies ) = /^([^:=\[]+):([^=].*|)\s*$/ )
    {
      # a rule header
      # note: "make[2]: Nothing to be done for `all'." isn't
      @targets = split( ' ', $targets );
      my @dependencies = split( ' ', $dependencies );
      # TO DO: this isn't exact on special kinds of rules

      foreach my $t (@targets)
      {
        if ( !@dependencies )
        {
          $csvh->print( *STDOUT, [$t] );
        }
        else
        {
          foreach my $d (@dependencies)
          {
            $csvh->print( *STDOUT, [ $t, $d ] );
          }
        }
      }
      $state = 'rule';
    }
    else
    {
      # some other kind of line, probably assignment or comment
      $state   = 'outside';
      @targets = ();
    }

    dinfo($state);
  }

  if ( $line ne '' )
  {
    oomph('ignoring last line because file ends with \\');
  }
}