#!/usr/bin/env perl
#
# uniqer - uniq, but removes duplicate lines in unsorted files as well
#
# $Id#
#
# memory hungry without -s ...

use warnings;
use strict;

use Getopt::Std;

my %opt;
getopts( 'h?se:', \%opt )
 or die "error parsing command line: $!\n";

HELP_MESSAGE()
 if grep { /^[h?]/ } keys %opt;

sub HELP_MESSAGE
{
  print STDERR <<ZZ;

Usage: $0 [-s] [-e expr] [file1 [file2 [...]]]

to print the lines in the input that are not equivalent to

  *some* previous line, if -s is not specified, or
  *the* previous line, if -s is specified;

where two lines are equivalent if

  they are the same string, if -e is not specified, or
  the results after applying xpr to them are the same string,
    if -e xpr is specified, where xpr is a Perl expression modifying \$_

Examples:

  uniqer -s file1

    is equivalent to the standard uniq command;

  uniqer file1

    omits all identical lines except their first occurrence;

  uniqer -e '\$_=lc'

    uses case-insensitive comparison

ZZ
  exit(0);
}

$| = 1;

my %seen;

while (<>)
{
  my $l = $_;
  eval $opt{e} if defined $opt{e};
  print $l unless $seen{$_};
  %seen = () if $opt{s};
  $seen{$_} = 1;
}