#!/usr/bin/env perl
#
# $Id$

use strict;
use warnings;

use Getopt::Std;
use Time::Piece;

my %opt;
getopts( 'achs:', \%opt );

$opt{h} and HELP_MESSAGE();

$opt{a} && $opt{c} and die "options -a and -c are incompatible\n";

if ( defined( $opt{s} ) && ( $opt{s} =~ /\D/ || !$opt{s} || $opt{s} > 39 ) )
{
  die "option -s takes a number of seconds between 1 and 59\n";
}

sub HELP_MESSAGE
{
  print STDERR <<ZZ;
Usage: $0 [-a] [-c] [-s nr] [inputfile]

to process a standard Apache access_log
and report the number of on-time and over-time requests per minute.
A request is 'over-time' if its timestamp
(which records the time processing the request started, in seconds)
is earlier than that of a previous requests
(i.e. earlier in the log, i.e. completed sooner).

Without the -a option, a header is printed,
followed by one line for each minute.

Options:

  -a  Print all requests, with whether they were on time (+) or not (-).
  -c  Also print lines for minutes without any requests.
      Does not make sense when -a is specified.
  -s nr
      Don't use minutes as intervals, but nr seconds intervals within each minute.
      Print the first second in each interval.
ZZ
  exit(0);
}

my $prevmin;
my %count_in_min;
my %count_past_min;
my $latest;

my $time_format = '%d/%b/%Y:%H:%M:%S %z';    # e.g. 31/Jan/2017:23:32:04 +0100
my $min_format  = '%d/%b/%Y:%H:%M';          # e.g. 31/Jan/2017:23:32

if ( $opt{s} )
{
  $min_format = '%d/%b/%Y:%H:%M:%S'          # e.g. 31/Jan/2017:23:32:20
}

if ( $opt{a} )
{
  if ( $opt{s} )
  {
    print "ONTIME\tOVERTIME\tMINUTE\rSECOND\n";
  }
  else
  {
    print "ONTIME\tOVERTIME\tMINUTE\n";
  }
}

sub print_min
{
  my ($min) = @_;
  my $min_to_print = Time::Piece::strftime( $min, $min_format );
  printf( "%s\t%s\t%s\n",
    map { defined($_) ? $_ : 0 }
     ( $count_in_min{$min}, $count_past_min{$min}, $min_to_print ) );
}

my @mins;
my %mins;

while (<>)
{
  my ($time) = /(?!^|\s)\[([^]]*)\](?=$|\s)/
   or die "Cannot find timestamp in log line: $_";

  my $min;

  eval { $min = Time::Piece->strptime( $time, $time_format ) }
   or die "timestamp in log is not in required format\n";

  if ( $opt{s} )
  {
    # round the time to the last interval
    $min -= $min->sec() % $opt{s};
  }
  else
  {
    # round the time to the minute
    $min -= $min->sec();
  }

  #warn "input time is $time, min is $min\n";

  push( @mins, $min ) if !$mins{$min}++;

  if ( !defined($prevmin) )
  {
    $prevmin = $min;
    $latest  = $min;
  }
  elsif ( $prevmin ne $min )
  {
    #print_min($prevmin);

    $prevmin = $min;
    $latest = $latest < $min ? $min : $latest;
  }

  if ( $min == $latest )
  {
    print "+ $_" if $opt{a};
    ++$count_in_min{$min};
  }
  else
  {
    print "- $_" if $opt{a};
    ++$count_past_min{$min};
  }
}

exit if $opt{a};

#@mins = sort { $a <=> $b } @mins; # will usually be sorted already

if ( $opt{c} && @mins )
{
  # add any empty minutes
  my @allmins = shift(@mins);

  while (@mins)
  {
    if ( $opt{s} )
    {
      for (
        my $mins = $allmins[-1] + $opt{s} ;
        $mins < $mins[0] && $mins < $allmins[-1] + 60 ;
        $mins += $opt{s}
       )
      {
        push( @allmins, $mins );
      }
    }

    for ( my $min = $allmins[-1] + 60 ; $min < $mins[0] ; $min += 60 )
    {
      if ( $opt{s} )
      {
        for (
          my $mins = $min + $opt{s} ;
          $mins < $mins[0] && $min < $min + 60 ;
          $mins += $opt{s}
         )
        {
          push( @allmins, $mins );
        }
      }

      push( @allmins, $min );
    }

    push( @allmins, shift(@mins) );
  }

  @mins = @allmins;
}

for my $min (@mins)
{
  print_min($min);
}