#!/usr/bin/env perl
#
# file-age-alert - prints a message when a file is over a given age
#
# $Id$

use strict;
use warnings;
use Getopt::Std;

my %opt;
getopts( 'f:hn:qx:', \%opt )
 or die "cannot parse command line\n";

$opt{h} and HELP_MESSAGE();

sub HELP_MESSAGE
{
  print STDERR <<ZZ;
Usage:
   $0 [-n min] [-x max] [-f fmt|-q] file [file2 [...]]

to print a message to standard output for each of the given files
that has been modified longer than the indicated number of seconds ago.

The exit code is the number of files for which this is the case.

Options:

  -n min

   The minimum number of seconds at which to issue the message.
   (Default: 60)

  -x min

   The maximum number of seconds at which to issue the message.
   (Default: infinity)

  -f fmt

   The format of the message.  Format specifiers:
      %f for the file name
      %m for the number of minutes
      %s for the number of seconds
         (after subtracting the minutes, if %m occurs)
   (Default: %f has not been modified in %m minutes %s seconds!)

  -q

   Do not print a message.

ZZ
  exit(0);
}

$opt{n} = 60 if !defined $opt{n};
$opt{f} = '%f has not been modified in %m minutes %s seconds!'
 if !defined $opt{f};

$opt{n} =~ /^\d+$/ or die "the value of -n must be a whole number\n";
!defined( $opt{x} ) || $opt{x} =~ /^\d+$/
 or die "the value of -n must be a whole number\n";

sub replace_with_in
{
  my ( $from, $to, $in ) = @_;
  join( $to, split( $from, $in, -1 ) );
}

@ARGV or die "supply at least one filename as argument\n";

my $nr_old_files = 0;

foreach my $f (@ARGV)
{
  my $mtime = ( stat $f )[9];

  if ( !defined $mtime )
  {
    warn "cannot determine age of $f\n";
    next;
  }

  my $age = time() - $mtime;

  if ( $age >= $opt{n} && ( !defined( $opt{x} ) || $age <= $opt{x} ) )
  {
    ++$nr_old_files;
    next if $opt{q};

    my $msg = $opt{f};
    my $sex = $msg =~ /%m/ ? $age % 60 : $age;
    $msg = replace_with_in( '%f', $ARGV[0],         $msg );
    $msg = replace_with_in( '%m', int( $age / 60 ), $msg );
    $msg = replace_with_in( '%s', $sex,        $msg );
    print $msg, "\n";
  }
}

exit($nr_old_files)