#!/usr/bin/env perl
#
# $Id$
#
# append - append files to other files, then remove the originals

use strict;
use warnings;

use Getopt::Std;
use File::Basename;

#--- command line parsing for options --#
#
my %opt;
getopts( 'ch?', \%opt );

if ( $opt{'h'} || $opt{'?'} )
{
  print STDERR <<ZZ;

Usage: $0 [-c] source1 [source2 [...]] target

to append the contents of source1, ..., to target.

If a source is a directory, all files in the directory are used.
If the target is a directory, appending happens to (the) file(s)
in the directory with the same name as the source(s).

If a target file doesn't exist, it is created.

Options:

  -c  do not remove the original source files.

ZZ
  exit(0);
}

#--- two auxiliary functions ---#
#

sub thesamefile
# whether the two filenames supplied as arguments point to the very same file
{
  my ( $f1, $f2 ) = @_;

  if ( !-e $f1 || !-e $f2 )
  {
    return 0;
  }

  my ( $dev1, $ino1 ) = stat($f1);
  my ( $dev2, $ino2 ) = stat($f2);

  return ( $dev1 eq $dev2 ) && ( $ino1 eq $ino2 );
}

sub append
{
  my ( $src, $tgt ) = @_;

  if ( !-e $src )
  {
    warn("$src does not exist, skipping it\n");
  }
  elsif ( &thesamefile( $src, $tgt ) )
  {
    warn("$src and $tgt are the same, skipping them\n");
  }
  elsif ( -d $src && -d $tgt )
  {
    # append every member of $src to the equally-named member of $tgt
    # leaving the unmatched members of $src alone
    foreach my $srcf ( glob("$src/*") )
    {
      &append( $srcf, $tgt );

      #if $src !~ /^\./;  # to exclude . and ..
    }
  }
  elsif ( -d $tgt )
  {
    # append $src to the equally-named member of $tgt
    # leaving it alone if no matching mmber exists
    foreach my $tgtf ( glob("$tgt/*") )
    {
      if ( basename($src) eq basename($tgtf) )
      {
        &append( $src, $tgtf );
      }
    }
  }
  elsif ( -d $src )
  {
    # don't do anything! - too risky
  }
  else
  {
    # append the non-directory $src to the non-directory $tgt
    warn("appending $src to $tgt\n");

    open( OUT, ">> $tgt" )
     or warn("cannot open output to '$tgt'\n");
    open( IN, "< $src" )
     or warn("cannot open input from '$src': $!\n");
    select(IN);
    undef($/);
    print OUT <IN>;
    close(IN)
     or warn("cannot close input from '$src': $!\n");
    close(OUT);

    ( $src eq '-' )
     or $opt{'c'}
     or unlink($src)
     or warn("cannot remove input file '$src': $!\n");
  }
}

#--- go go go! ---#
#

my $target = pop(@ARGV) || '-';
@ARGV || ( @ARGV = ('-') );    # so there

foreach my $arg (@ARGV)
{
  &append( $arg, $target );
}