#!/usr/bin/env perl
#
# count - count identical lines in file
#
# $Id$

use warnings;
use strict;

use Getopt::Std;

my %opt;
getopts( 'hs', \%opt );

&help if $opt{h};

sub help
{
  print STDERR <<ZZ;

Usage:

  $0 [-s] [file [file2 [...]]]

to print, in order of first occurrence, each different input line,
preceded by the number of times it occurs and a space.

Option:

  -s  Print the counts of *consecutive* identical lines.
      This requires a lot less memory,
      and yields the same result if the input is sorted.

ZZ
  exit(0);
}

if ( $opt{s} )
{
  my $prevl = '';
  my $count = 0;

  while (<>)
  {
    if ( $_ eq $prevl )
    {
      ++$count;
    }
    else
    {
      print "$count $prevl" if $count;
      $prevl = $_;
      $count = 1;
    }
  }
  print "$count $prevl" if $count;
}
else
{
  my @lines;
  my %count;

  while (<>)
  {
    if ( !$count{$_}++ )
    {
      # this is the first time we encounter this line
      push( @lines, $_ );
    }
  }

  foreach my $l (@lines)
  {
    print "$count{$l} $l";
  }
}