#!/usr/bin/env perl
#
# csvcombine - combine multiple CSV files into one
#
# $Id$

use warnings;
use strict;

use Getopt::Std;
use Text::CSV_XS;

my %opt;
getopts( 'hft:', \%opt );

&help if $opt{'h'};

my $sep        = $opt{'t'} // ',';
my $add_header = $opt{'f'} // 0;

@ARGV = ('-') if !@ARGV;

sub help
{
  print STDERR <<ZZ;

Usage: $0 [-t sep] [input1 [input2 [...]]]

  to combine the lines of the inputs in question.

Each kth line of output will be the concatenation of
the kth lines of input, separated by the separation string.
Inputs that are too short are padded with empty lines.

An input is either a filename or a special name.
A special name can be -, +, or =n, where n is an integer.
(Note: if you get an error: Directory stack not that deep,
when using the latter, this is caused by the shell calling this script;
in that case, escape or quote the argument(s) in question.)

If an input is specified twice, it is read once and reused.

The special input - indicates standard input.
If no inputs are specified at all, - is implied.

The special input + indicates an imaginary input
consisting of line numbers, one per line, starting with 1,
running to the maximum length of the other inputs.

The special input =n, for any integer n, indicates an imaginary input
consisting of the integer n, on each line,
running to the maximum length of the other inputs.

Options:

  -f
    prepend an output line listing the input names

  -t sep
     use the given string as the separator, instead of a comma.

ZZ
  exit(0);
}

my %fn2lines;
my $maxnrlines = 0;

foreach my $f (@ARGV)
{
  if ( $f eq '+' || $f =~ /^=-?\d+/ )
  {
    # special cases
    next;
  }

  if ( defined $fn2lines{$f} )
  {
    # already read
    next;
  }

  my @lines;

  if ( $f eq '-' )
  {
    @lines = <STDIN>;
  }
  elsif ( !open( my $infh, '<', $f ) )
  {
    warn "cannot open for reading, skipped: $f\n";
    next;
  }
  else
  {
    @lines = <$infh>;
    close($infh);
  }

  chomp for @lines;

  $fn2lines{$f} = [@lines];
  my $nrlines = scalar(@lines);
  $maxnrlines = $nrlines if $nrlines > $maxnrlines;
}

if ($add_header)
{
  print join( $sep, @ARGV ), $/;
}

foreach my $i ( 0 .. $maxnrlines - 1 )
{
  my @combined = map {
    $ARGV[$_] eq '+' ? $i
     : (
        $ARGV[$_] =~ /^=(-?\d+)$/ ? $1
      : $fn2lines{ $ARGV[$_] }->[$i] // ''
     )
  } 0 .. $#ARGV;

  print join( $sep, @combined ), $/;
}