#!/usr/bin/env perl
#
# hdr2col - prepend (elements from) lines from files to subsequent lines
#
# $Id$

use warnings;
use strict;

use Getopt::Std;

my $me = $0;
$me =~ s#.*/##;
my $verbosity = 0;

sub ehm

 # arguments: tracelevel and message
{
  warn( "$me: ", @_, "\n" ) if shift(@_) <= $verbosity;
}

sub puke

 # arguments: message
{
  die( "$me: fatal error: ", @_, "\n" );
}

sub usage
{
  print STDERR "Fatal error: ", @_, "\n" if @_;

  print STDERR <<ZZ;

Usage: $0 [-e perlexpr] [file1 [file2 [...]]]

  matches lines in a file against the Perl expression 'perlexpr';
  every matching line is prepended to all following non-matching lines;
  by modifying \$_ in the perlexpr, a different prefix can be used

  Examples:

    ls -R .. | $me -e 'm#^\\\.\\\.# && s#:\$#/#'  # makes it 'find'-like

    $me -e '/^/' some-file  # prints nothing, because every line will match

ZZ
  exit( scalar(@_) );
}

#--- cmdline parse ---#
#

my %opt;
getopts( 'h?ve:', \%opt );

my $xpr = $opt{'e'}
 or &usage("-e perlexpr is required");

( $opt{'h'} || $opt{'?'} )
 and &usage;

#--- the real work ---#
#

my $prefix = '';

while (<>)
{
  chop;

  if ( eval($xpr) )
  {
    $prefix = $_;
    &ehm( 1, "using prefix '$prefix'" );
  }
  else
  {
    #&ehm(2,"prefixing '$_'");
    $_ = $prefix . $_ . "\n";
    print;
  }
}