#!/usr/bin/env perl
#
# lm - last modified file (including directories)
#
# $Id$

use strict;
use warnings;
use Getopt::Std;
use File::Find;
use POSIX qw(strftime);
use List::Util qw(sum);

no warnings 'File::Find';

my %opt;
getopts( 'h?dfF:Lm:M:n:tT', \%opt );

if ( $opt{h} || $opt{'?'} )
{
  HELP_MESSAGE();
}

sub HELP_MESSAGE
{
  print STDERR <<ZZ;

Usage: lm [-m d] [-M d] [-n d] [-L] [-d|-f|-t] [-F fmt] [file1 [file2 [...]]]

to search each of the given files or directories recursively,
listing for each the file found with the latest modification time.

If no arguments are specified, the currect directory is searched.

Options:

  -F fmt

     Use the given format string.
     Valid conversion specifications:

       %f - the (possibly relative) pathname to the file
       %a - the argument from which the file was found
       %m{fmt}
            where fmt is a format string to strftime()
            that does not contain }
          - the last modification time of the file

     The default format is %f (only list the file found).

  -L

     Follow symbolic links.

  -m nrdays

     Only consider files that have been modified at most nrdays ago.

  -M nrdays

     Only consider files that have been modified at least nrdays ago.

  -n nrfiles

     List no more than the given number of files (1 by default).

  -d

     Only list directories.

  -f

     Only list plain text files.

  -T

     Only list ASCII or UTF-8 text files (heuristic guess).

Examples:

  lm -F '%a,%f,%m{%Y%m%d%H%M%S}'

   List the newest file or directory under .
   with a numerically sortable modification time:

      .,./bin/.lm.swp,20141029084459

  env LANG=en_GB lm -fF '%a,%f,%m{%c}' -m 730

   List the newest file under . among the ones changed 
   in the last two years, with the modification time in British format:

      .,./bin/.lm.swp,Wed 29 Oct 2014 08:44:59 CET

  env LANG=en_GB TZ=0 lm -m 730 -fF '%a,%f,%m{%c}'

   The same, with the timezone set to GMT.


ZZ
  exit(0);
}

foreach my $m (qw(m M n))
{
  my $optm = $opt{$m};

  if ( defined($optm) && $optm =~ /\D/ )
  {
    die "$0: $m must be followed by a nonnegative integer\n";
  }
}

if ( sum( map { 0 + ( $opt{$_} // 0 ) } qw(d f T) ) > 1 )
{
  die "$0: specify at most one of the options -d, -f and -T\n";
}

$opt{F} = '%f' if !defined $opt{F};
$opt{n} = 1    if !defined $opt{n};

foreach ( @ARGV ? @ARGV : '.' )
{
  list_last_modified_files($_);
}

sub list_last_modified_files
{
  my ($arg) = @_;

  my @latest_filename = ();    # the top n filenames
  my @latest_mtime    = ();    # the top n mtimes, in the same order

  find(
    {
      follow      => $opt{L},
      follow_skip => 2,
      wanted      => sub {
        my $mtime = ( stat($_) )[9];
        return if !defined($mtime);
        return if defined( $opt{m} ) && -M $_ > $opt{m};
        return if defined( $opt{M} ) && -M $_ < $opt{M};
        return if $opt{d} && !-d $_;
        return if $opt{f} && !-f $_;
        return if $opt{T} && !-T $_;

        my $filename = $File::Find::name;

        # insert the file into the top n, if it belongs there

        my $inserted = 0;

        for my $i ( 0 .. $#latest_filename )
        {
          if ( $mtime > $latest_mtime[$i] )
          {
            # insert this item
            splice( @latest_filename, $i, 1, $filename );
            splice( @latest_mtime,    $i, 1, $mtime );
            $inserted = 1;
            last;
          }
        }

        if ( !$inserted && scalar(@latest_filename) < $opt{n} )
        {
          push( @latest_filename, $filename );
          push( @latest_mtime,    $mtime );
        }
        elsif ( $inserted && scalar(@latest_filename) > $opt{n} )
        {
          pop(@latest_filename);
          pop(@latest_mtime);
        }
      }
    },
    $arg
  );

  for my $i ( 0 .. $#latest_filename )
  {
    print_file( $latest_filename[$i], $latest_mtime[$i], $arg );
  }
}

sub print_file
{
  my ( $filepath, $mtime, $arg ) = @_;

  local ($_) = $opt{F};
  my @lmtime = localtime($mtime);
  s/%a/$arg/g;
  s/%f/$filepath/g;
  s/%m\{([^}]*)}/strftime($1,@lmtime)/e;
  print "$_\n";
}