#!/usr/bin/env perl
#
# loo - lines of ode - counts lines and chars without surrounding whitespace
#
# $Id$

use strict;
use warnings;

use Getopt::Std;

my %opt;
getopts( 'htw', \%opt );

if ( $opt{'h'} )
{
  print STDERR <<ZZ;
Usage: $0 [-tw] [file1 [file2 [...]]]

to count lines and chars, discarding leading and trailing whitespace
and all-whitespace lines;

with -t, adds the total, like wc(1);
with -w, includes all-whitespace lines into the line count.

ZZ
  exit(0);
}

@ARGV or push( @ARGV, '-' );

my $totallines = 0;
my $totalchars = 0;

foreach my $f (@ARGV)
{
  if ( ( $f eq '-' ) )
  {
    if ( !open( IN, '<-' ) )
    {
      warn "cannot read from standard input: $!\n";
      next;
    }
  }
  elsif ( !-T $f )
  {
    warn "not a text file, skipped: $f\n";
    next;
  }
  elsif ( !open( IN, '<', $f ) )
  {
    warn "not readable, skipped: $f\n";
    next;
  }

  my $nrchars = 0;
  my $nrlines = 0;

  while (<IN>)
  {
    chomp;

    if ( /\S.*\S/ || /\S/ )
    {
      $nrchars += length($&);
      $nrlines += 1;
    }
    elsif ( $opt{'w'} )
    {
      $nrlines += 1;
    }
  }

  close(IN);

  print "$nrlines\t$nrchars\t$f\n";

  $totalchars += $nrchars;
  $totallines += $nrlines;
}

if ( $opt{'t'} )
{
  print "$totallines\t$totalchars\ttotal\n";
}