#!/usr/bin/env perl
#
# only - print all lines whose first field is in the given file
#
# see also: ./except
#
# $Id$

use strict;
use warnings;

use Getopt::Std;

my %opt;
getopts( 'hx', \%opt );

HELP_MESSAGE() if $opt{h};

sub HELP_MESSAGE
{
  warn join( ' ', 'Error:', @_ ), "\n" if @_;

  print STDERR <<ZZ;

Usage: $0 [-x] file1 [file2 [...]]

to print all lines in the last given input file,
or standard input if only one argument is given,
that also occur in the previous given files,
or if -x is specified, do *not* occur in those files.

The pseudo-filename - denotes standard input.

ZZ

  exit( !!@_ );
}

@ARGV or HELP_MESSAGE('specify at least one argument');

@ARGV == 1 and push( @ARGV, '-' );

my %seen;

sub as_input
{
  $_[0] eq '-' ? ( $_[0] ) : ( '<', $_[0] );
}

while ( @ARGV > 1 )
{
  my $f = shift(@ARGV);

  open( my $fh, as_input($f) )
   or do { warn "cannot open $f, skipped\n"; next };

  while (<$fh>) { ++$seen{$_} }

  close($fh);
}

{
  my $f = shift(@ARGV);

  open( my $fh, as_input($f) ) // die "cannot open $f, no output generated\n";

  if ( $opt{x} )
  {
    while (<$fh>) { print if !$seen{$_} }
  }
  else
  {
    while (<$fh>) { print if $seen{$_} }
  }

  close($fh)
}