#!/usr/bin/env perl
#
# picasaweb - list or get Picasaweb albums
#
# $Id$
#
use strict;
use warnings;

use Net::Google::PicasaWeb;
use LWP::Protocol::https;    # or the login will fail
use Getopt::Std;

my @valid_sizes =
 qw(94 110 128 200 220 288 320 400 512 576 640 720 800 912 1024 1152 1280 1440 1600);
my $valid_sizes = join( ', ', @valid_sizes );

my %opt;
getopts( 'hu:p:m:rlz', \%opt );
$opt{h} and HELP_MESSAGE();
( $opt{l} || $opt{z} ) or die "Specify either -l or -z; specify -h for help\n.";
( !$opt{l} || !$opt{z} )
 or die "Specify either -l or -z; specify -h for help\n.";

sub HELP_MESSAGE
{
  print STDERR <<ZZ;
Usage: $0 [-u username] [-p password] [-l|-z] [-r] [-m maxsize] [albumname [albumname2 [...]]]

to list or retrieve the contents of PicasaWeb image albums.

Arguments:

  Arguments select albums.
  Without -r, they must be exact titles of albums;
  with -r, regular expressions matched against the album titles.
  Without any arguments, all albums are used.

Options:

  -l

    List lists all pictures in the selected albums.
    Either -l or -z must be specified.

  -r

    Interpret the album selection argument(s) (if any)
    as regular expressions.  E.g. an argument of ^T will now
    select all albums of which the title starts with a capital T.

  -z

    Retrieves all pictures in the selected albums into a ZIP archive
    written to standard output.  Either -l or -z must be specified.

  -u username

    Specifies the Picasaweb username (an email address).
    If this option is missing, the username is asked interactively.

  -p password

    Specifies the Picasaweb password for the user.
    If this option is missing, the password is asked interactively.

  -m maxsize

    Height or width (whatever is larger) of the images to return.
    The size value must be one of

      $valid_sizes.

ZZ
  exit(0);
}

my $svc = new Net::Google::PicasaWeb
 or die "Cannot create PicasaWeb service: $!\n";

my $list = $opt{l} // 0;
my $zip  = $opt{z} // 0;

!defined( $opt{m} ) || grep { $_ eq $opt{m} } @valid_sizes
 or die "The value of -m must be one of the following numbers: $valid_sizes.\n";

my %list_opt = $opt{m} ? ( imgmax => $opt{m} ) : ();

my $username = $opt{u} // ask('Username');
my $password = $opt{p} // ask( 'Password', '*' );

$svc->login( $username, $password )
 or die "Cannot log in as user '$username' with given password.\n";

my @albums = $svc->list_albums( user_id => $username )
 or die "Cannot find any albums for user '$username': $!\n";

if (@ARGV)
{
  if ( $opt{r} )
  {
    my $arg_rx = join( '|', @ARGV );
    $arg_rx = qr($arg_rx);

    @albums = grep { $_->title =~ /$arg_rx/ } @albums
     or die "No matching albums were found.\n";
  }
  else
  {
    my %in_arg = map { $_ => 1 } @ARGV;

    @albums = grep { $in_arg{ $_->title } } @albums
     or die "None of the listed albums were found.\n";
  }
}

if ($list)
{
  list(@albums);
}
if ($zip)
{
  get(@albums);
}

exit(0);

#--- auxiliaries ---#
#

sub ask
# slightly modified from http://www.perlmonks.org/?node_id=886306
{
  use Term::ReadKey;

  my ( $prompt, $repl ) = @_;
  my $pword;
  my $key;
  open( my $out_fh, '>', '/dev/tty' )
   or die "Cannot write to tty: $!\n";
  my $stdout = *STDOUT;
  select($out_fh);
  local $| = 1;    # Turn off STDOUT buffering for immediate response
  print "$prompt: ";
  ReadMode 4;      # Change to Raw Mode, disable Ctrl-C

  while (1)
  {
    while ( !defined( $key = ReadKey(-1) ) ) { }

    if ( $key =~ /^[\r\n]/ )
    {              # if Enter was pressed...
      print $key;    # print a newline
      last;          # and get out of here
    }
    print( $repl // $key );
    $pword .= $key;
  }
  ReadMode 0;        # Reset tty mode before exiting. <==IMPORTANT
  select($stdout);
  return $pword;
}

sub list
{
  foreach my $album (@_)
  {
    my @photos = $album->list_media_entries(%list_opt);
    print scalar(@photos), ' images in ', $album->title, "\n";

    foreach my $me (@photos)
    {
      my $content = $me->photo->content;
      printf( "%s in %s\n", identify($me), $album->title );
    }
  }
}

sub get
{
  use Archive::Zip;
  use URI::Escape;

  my $zip = Archive::Zip->new();

  foreach my $album (@_)
  {
    foreach my $me ( $album->list_media_entries(%list_opt) )
    {
      my $content = $me->photo->content;
      warn sprintf( "%s in %s\n", identify($me), $album->title );
      my $member_name =
       join( '/', map { uri_escape($_) } ( $album->title, $me->title ) );
      $zip->addString( $content->fetch(), $member_name );
    }
  }
  $zip->writeToFileHandle(*STDOUT);
}

sub identify
{
  my ($me) = @_;
  sprintf(
    '%s (%s, original %sx%s, also in %s)',
    $me->title,
    $me->photo->content->mime_type,
    $me->height,
    $me->width,
    join( ', ',
      map { sprintf( '%sx%s', $_->height, $_->width ) } $me->photo->thumbnails )
  );
}