#!/usr/bin/env perl
#
# renamep - rename(1) but with Perl commands
#
# $Id$

use warnings;
use strict;

use Getopt::Std;

my %opt;
getopts( 'f:hnv', \%opt );

HELP_MESSAGE() if $opt{'h'};

sub HELP_MESSAGE
{
  print STDERR <<ZZ;

Usage: $0 [-h] [-n] [-v] [-f fmt] expr file1 [file2 [...]]

  to rename (or manipulate otherwise) the files given,
  using the Perl code given as the first argument.

Examples:

  $0 's/\.htm\$/.html' *.htm

renames all files with extension .htm to have extension .htm.

  $0 -f 'cp -p %s %s' 's/\.htm\$/.html' *.htm

copies them instead, using the cp command with the -p option.

Options:

  -f fmt

    Instead of renaming the files, runs the specified command.
    Use %s (twice) as a placeholder for the filenames.
    The command line is obtained using Perl's sprintf().

  -h
    Don't do anything except to print this help text.

  -n
    Don't actually execute the renames.

  -v
    List the renames executed and warn when a filename does not change.

ZZ

  exit(0);

}

sub ehm
{
  warn join( ' ', "$0:", @_ ), "\n";
}

sub ehm_v
{
  ehm(@_) if $opt{v};
}

sub oomph
{
  ehm( 'fatal error, use -h for help:', @_ );
  exit(-1);
}

@ARGV > 1 or oomph('provide at least 2 arguments');

my $code = shift(@ARGV);

{
  local $_ = '';

  if ( !defined eval $code )
  {
    $@ =~ s# at .*$/##;
    oomph( "$code is invalid Perl code", $@ ? ':' : '', $@ );
  }
}

foreach my $f (@ARGV)
{
  local $_ = $f;
  eval $code;
  my $g = $_;

  if ( $g eq $f )
  {
    ehm_v( 'unaffected filename:', $f );
    next;
  }

  my $action = $opt{f} ? sprintf( $opt{f}, $f, $g ) : "renaming $f to $g";
  ehm_v($action);

  $opt{n}
   or process( $f, $g )
   or ehm( $action, 'failed with error:', $! );
}

sub process
{
  if ( $opt{f} )
  {
    !system( sprintf( $opt{f}, @_ ) );
  }
  else
  {
    my ( $f, $g ) = @_;
    # rename(@_) throws a compile error!
    rename( $f, $g );
  }
}