#!/usr/bin/env perl
#
# unixifn - Unixify filenames
#
# $Id$

# the code could be cleaner, I'll admit

use strict;
use warnings;

use Getopt::Std;

my %opt;
getopts( 'hnvudst:', \%opt );

if ( $opt{'h'} || !@ARGV )
{
  print STDERR <<ZZ;

Usage:
  $0 filename [-n] [-v] [-t s|-u|-d] [-s] [filename2 [...]]]
  to remove some Unix-unfriendly characters from the given filename(s)

By default, unfriendly characters are replaced with a hyphen, -

Friendly characters are letters, digits, dot, slash and backslash.

Options:
  -t s
      replace them with the given string (instead of a hyphen)
  -s  replace sequences of the given string with one, unless -u/-d is used
  -d  URL-de-escape any URL-escaped characters (undoes -u)
  -u  URL-escape any characters that need to be in URLs
  -v  show the renames
  -n  do not actually perform the renaming (useful with -v)
  -f  overwrite any existing file
ZZ
  exit(0);
}

my $unfriendly_rx = qr([^a-zA-Z0-9\\/.%]);

sub urlescape
{
  my $res = $_[0];
  $res =~ s#$unfriendly_rx#sprintf("%%%02lx",unpack('C',$&))#ge;
  $res;
}

sub urlunescape
{
  my $res = $_[0];
  $res =~ s/%([\dA-Fa-f][\dA-Fa-f])/pack("C",hex($1))/ge;
  $res;
}

sub substitute

 # non-invertible
{
  #my $repl = quotemeta($_[0]);  # quotes too much. get this right some day
  my $repl  = $_[0];
  my $qrepl = quotemeta($repl);

  sub {
    my $res = $_[0];
    $res =~ s#$unfriendly_rx#$repl#g;
    $res =~ s#$qrepl+#$repl#g if $opt{'s'};
    $res;
   }
}

my $transform =
   $opt{'u'} ? \&urlescape
 : $opt{'d'} ? \&urlunescape
 : substitute( defined( $opt{'t'} ) ? $opt{'t'} : '-' );

foreach my $f (@ARGV)
{
  my $g = &$transform($f);
  next if $g eq $f;
  warn "$f -> $g\n" if $opt{'v'};

  if ( -e $g && !$opt{'f'} )
  {
    warn "cannot rename: $g already exists\n";
  }
  elsif ( !$opt{'n'} )
  {
    rename( $f, $g ) or warn "failed to rename '$f' to '$g': $!\n";
  }
}