#!/usr/bin/env perl
#
# $Id$

use strict;
use warnings;

use Getopt::Std;
use Text::CSV;

my %opt;
getopts( 'hp:r:t:', \%opt );

HELP_MESSAGE() if $opt{h};

my $sep = $opt{t} // ',';

sub HELP_MESSAGE
{
  print STDERR <<ZZ;

Usage: $0 [-t sep] [-r perlexpr] [-p perlexpr] [csvfile]

to interpret the CSV file(s) as relational tables,
rename their column names using the -r expression, if given,
and output the relational join of the columns of which the name
doesn't become empty and on which the -p expression, if given, is true.

The result is written to standard output in CSV format.

Options:

  -p perlexpr  A Perl expression used to select columns by name.
  -r perlexpr  A Perl expression used to rename columns.
  -t sep       The CSV field separator; if omitted, a comma is used.

Note that this is operation cannot be expressed in a relational algebra,
because its operations are schema-dependent.
Also note that columns in the output (or input) may have duplicate
names or names invalid to relational interpretation (with Perl's DBD::CSV).

ZZ
  exit(0);
}

my $csvh =
 Text::CSV->new( { quote_space => 0, sep_char => $sep, eol => $/ } )
 or puke('CSV reader/writer creation failed');
# not quite correct: we should take all settings from $dbh, e.g. encoding

my $header = $csvh->getline(*ARGV)
 or die "fatal error: no input\n";

my @r_header =
 defined( $opt{r} )
 ? ( map { eval $opt{r}; $_ } @$header )
 : @$header;
my @matches = map { (!defined( $opt{p} ) || eval $opt{p}) + 0 } @r_header;
my @cols_to_print = grep { $matches[$_] } 0 .. $#r_header;

$csvh->print( *STDOUT, [ map { $r_header[$_] } @cols_to_print ] );

while ( my $r = $csvh->getline(*ARGV) )
{
  $csvh->print( *STDOUT, [ map { $r->[$_] } @cols_to_print ] );
}