#!/usr/bin/env perl
#
# catalina-out-select - print selected lines from catalina.out
#
# $Id$

# Usage: e.g. catalina-out-select ERROR WARN /var/lib/tomcat7/logs/catalina.out

use strict;
use warnings;
use Getopt::Std;

my %opt;
getopts( 'he:v:', \%opt );

HELP_MESSAGE() if $opt{h};

# sloppy: disregard argument order
my @a_rx = grep { /^[A-Z]+$/ } @ARGV;
@ARGV = grep { !/^[A-Z]+$/ } @ARGV;

my $entry_start_tx =
 qr/^\d.+\d\s+([A-Z]{4,})/;    # the start of an entry in catalina.log

my ($a_rx) = @a_rx ? map { qr($_) } join( '|', @a_rx ) : undef;
my $e_rx = defined( $opt{e} ) ? qr($opt{e}) : undef;
my $v_rx = defined( $opt{v} ) ? qr($opt{v}) : undef;

doit();

exit(0);

sub HELP_MESSAGE
{
  print STDERR <<ZZ;

Usage:

  $0 [-e regex] [-v regex] LEVEL [LEVEL [...]]] [file [file [...]]]

to selectively display records from the input (usually, catalina.out).

Arguments:

  Without them, standard input is used.

  All-capital arguments are matched against the log entry's error level
  (SEVERE, ERROR, WARN, INFO or DEBUG).  All matching entries are used.
  Without such arguments, all entries are used.

  All other arguments are taken to be input files.
  Without such arguments, standard input is used.

Options:

  -h

    Only show this help text.

  -e regex

    Only display records whose entire text matches regex,
    which must be a Perl regular expression.

  -v regex

    Only display records whose entire text doesn't regex.

Examples:

  $0 SEVERE ERROR

    Show all records with error level SEVERE or ERROR.

  $0 -v incompatible ERROR

    Show all ERROR records without the text 'incompatible'.

ZZ

  exit(0);
}

sub doit
{
  my $level;
  my @entry;

  while (<>)
  {
    if ( my ($nextlevel) = /$entry_start_tx/ )
    {
      # the next entry starts here
      process_entry( $level, @entry ) if defined $level;
      @entry = ($_);
      $level = $nextlevel;
    }
    else
    {
      push( @entry, $_ );
    }
  }

  process_entry( $level, @entry );
}

sub process_entry
{
  my $level = shift(@_);
  my $entry = join( '', @_ );

  return if defined($a_rx) && $level !~ /$a_rx/;
  return if defined($e_rx) && $entry !~ /$e_rx/;
  return if defined($v_rx) && $entry =~ /$v_rx/;

  print STDOUT $entry;
}