#!/usr/bin/env perl
#
# makemanyfiles
#
# $Id$

use strict;
use warnings;

use Getopt::Std;
use File::Basename qw(dirname basename);

my %opt;
getopts( 'b:hn:v', \%opt );

my $default_nr_files = 1000;
my $default_nr_bytes = 0;

sub HELP_MESSAGE
{
  my $me = basename($0);

  print STDERR <<ZZ;
Usage: $me [-v] [-b nr_bytes] [-n nr_files]

to create nr_files files ($default_nr_files by default)
each of nr_bytes bytes ($default_nr_bytes by default).

Files are created in a directory tree; files and directories
are numbered from 0.

Preexisting files of the same name will be overwritten;
preexisting directories of the same name cause a fatal error.

With -v, progress (writing each file) is reported.

ZZ
  exit(0);
}

$opt{h} and HELP_MESSAGE();

my $nr_bytes = $opt{b} // $default_nr_bytes;
my $nr_files = $opt{n} // $default_nr_files;
my $verbose = $opt{v} // 0;
my $last_file = $nr_files - 1;
my $maxlength = length($last_file);

sub zeropadded
{
  sprintf( '%.' . $maxlength . 'd', $_[0] );
}

sub havedirfor
# returns 1 for success, 0 for failure
{
  my ($f) = @_;

  -d $f and return 1;

  my $p = dirname($f);

  $p eq $f and return 1;    # root dir

  havedirfor($p) or return 0;

  -d $p or mkdir($p);
}

sub yuck
{
  die( join( ' ', "$0: fatal error:", @_ ), "\n" );
}

foreach my $n ( 0 .. $last_file )
{
  my $f = join( '/', split( //, zeropadded($n) ) );
  warn "writing $nr_bytes bytes to file $f\n" if $verbose;
  havedirfor($f) or yuck("cannot create directory for $f");
  open( my $fh, '>', $f ) or yuck("cannot write to $f");
  $nr_bytes and print $fh ( '.' x ( $nr_bytes - 1 ) ) . "\n";
  close($fh) or yuck("error on closing $f\n");
}